; $Header: SubrocAttack.txt   Thu Jul 24 17:05:51 EDT 2003   mike $
; $Revision: 3 $
; $Copyrt1: Copyright (c) 2003, Sonalysts, Inc.  All rights reserved. $
;

var firing
var initx
var inity
var apexrng
var currng
var ordalt
var ordalt2
var ordptch

IF Init THEN {
	firing = false
	initx = ownx
	inity = owny
	apexrng = ( xyrng ( tgtx - initx ) ( tgty - inity ) * 1.01 )
	DebugOut "Asroc tgt x y apexrng"
	DebugValueOut tgtx
	DebugValueOut tgty
	DebugValueOut apexrng
} ELSE {
	IF WeaponAway THEN {
		Shutdown
	} ELSE {
		currng = xyrng ( ownx - initx ) ( owny - inity )
		IF currng > apexrng AND ( NOT firing ) THEN {
			FireBest
			DebugOut "Asroc drop"
			DebugValueOut currng
			firing = true
		} ELSE {
			IF NOT firing THEN {
					SetCrs GetEntVar "PreenableCourse"
					SetSpd MaxSpd
					ordalt = ( abs ( currng - apexrng ) / apexrng )
					ordalt = ( MaxAlt * ( 1 - ( ordalt * ordalt ) ) + 45 )
					ordalt2 = ( abs ( currng + 1 - apexrng ) / apexrng )
					ordalt2 = ( MaxAlt * ( 1 - ( ordalt2 * ordalt2 ) ) + 45 )
					ordptch = xybrg ( ordalt2 - ordalt ) 1
					IF ordptch > 180 THEN {
						ordptch = ( ordptch - 360 )
					} ENDIF
					SetPitch ordptch
;					DebugOut "Ballistic Alt"
;					DebugValueOut ordalt
;					DebugOut "Ballistic Ptch"
;					DebugValueOut ordptch
			} ENDIF
		} ENDIF
	} ENDIF
} ENDIF
